Você pode baixar essa instalação clicando aqui. As instruções de como instalar estão dentro do arquivo “instalar.txt“.

Hoje o Grep Replace já está na distribuição oficial do GExperts faz algum tempo. Mas, por outro lado, o código fonte do DelForEx, o formatador de código fonte Delphi que muita gente usa, foi doado para o GExperts algum tempo atrás. Como não foi atualizado para formatar todas os novos recursos de linguagem adicionados recentemente no Delphi, não está na distribuição oficial ainda. Mesmo assim teve alguns incrementos e correções. Se o formatador de código fonte te interessa, se você quer acompanhar outras novas funcionalidades, ou quem sabe até escrever algum expert para ajudar em alguma tarefa chata do dia a dia, escrevi esse guia rápido para se manter atualizado com a distribuição do GExperts. De bônus, primeiro passo dele serve como base pra qualquer outro projeto do SourceForge que você tenha interesse.

Passo 1: Baixando o código fonte

Apesar de o GExperts oferecer zips diários com os fontes, é uma solução trabalhosa para se manter atualizado, sendo só uma alternativa para quem não consegue acessar o repositório CVS por algum motivo.

Acessar o servidor de CVS diretamente é a melhor opção para baixar qualquer atualização facilmente, e se você pretende fazer qualquer customização na sua própria versão, mesclar essas alterações sem muito esforço. Para baixar os fontes dessa forma, recomendo usar o TortoiseCVS, mas qualquer outro cliente de CVS que preferir também funciona. Depois de instalado, vá até o windows explorer e clique com o botão direito em alguma pasta que queira guardar os fontes, selecione CheckOut, e usar o CVSROOT como :pserver:anonymous@gexperts.cvs.sourceforge.net:/cvsroot/gexperts. Pela interface web do repositório de CVS do projeto, descobri que nome do módulo é “gexperts”. Então é só apertar OK e esperar que todos os arquivos sejam baixados. Depois, sempre que quiser receber as atualizações feitas no projeto, é só clicar com o botão direito na pasta e utilizar a opção “Update” do TortoiseCVS.

Passo 2: Compilando a DLL

O GExperts vem com diferentes projetos para cada versão do Delphi. É só abrir o apropriado para a versão que você usa, e compilar. No meu caso, escolhi o GExpertsBDS2006.bdsproj, e gerei o arquivo GExpertsBDS2006.dll. Fácil. Se for para uso do dia-a-dia, desligue a opção para gerar informações de Debug, na aba Compiler das opções do projeto. Se essa opção ficar ligada, o GExperts vai enviar várias mensagens de depuração para uma janelinha de debug que ele cria na bandeja do sistema.

Se você quer testar o formatador de código fonte que mencionei anteriormente, basta adicionar os arquivos das pastas Src\Formatter, Src\Formatter\Common e Src\Formatter\Engine no projeto e recompilar.

Passo 3: Instalando no Delphi

Antes de instalar essa DLL que acabou de ser compilada no Delphi, recomendo copiá-la para outra pasta. Explico porquê: da próxima vez que você baixar atualizações e quiser compilar novamente, ela vai estar instalada e carregada pelo Delphi. E então, é claro, você não vai conseguir substituir um arquivo em uso, sendo necessário removê-la, compilar e instalar de novo. Assim, facilitamos esse trabalho no futuro.

Após copiar a DLL, temos que fazer manualmente um passo que o instalador do GExperts faria: atualizar a configuração do Delphi no registro para que ela seja carregada. Basta abrir o RegEdit, navega para HKEY_CURRENT_USER\Software\Borland\BDS\4.0\Experts substuindo BDS\4.0 pela sua versão do Delphi (da versão 7 e anteriores é Delphi\n.0, e para frente, BDS\n.0). BDS 4.0 é o Delphi 2006. Você pode criar a chave experts se ela não existir. Nesta chave crie uma nova entrada com o nome “GExperts” e no conteúdo coloque o caminho completo da DLL que foi compilada anteriormente.

Agora basta carregar o Delphi e aproveitar as novas funcionalidades.

Se você tem interesse em desenvolver experts para facilitar sua vida, não deixe de ler os FAQs de desenvolvimento do gexperts e da Open Tools API. E, é claro, futuros artigos aqui.

Já aconteceu de você ter uma idéia de algo que poderia ter na IDE do Delphi para facilitar sua vida? Uma opção é fazer uma solicitação e esperar que seja implementado. Uma outra opção é arregaçar a mangas e implementar você mesmo.

A IDE do Delphi é bastante extensível. Existe uma API chamada Open Tools API (OTA) que permite customizar vários pontos da IDE, integrando seu código em várias partes. Apesar de a documentação ser um pouco escassa e ser um pouco difícil de descobrir algumas coisas, é bem possível escrever experts para quase tudo na IDE.

Por enquanto, vou deixar a implementação do seu expert com você. Vou mostrar como passar pelo primeiro problema no meio do caminho, carregar seu expert integrado na IDE.

Um expert geralmente é uma BPL (pode ser uma DLL também, mas é um pouco mais complicado). Crie, então um novo package, salve um algum lugar e adicione uma unit nele.

A OTA é baseada em interfaces, e a maioria delas está definida em ToolsAPI.pas. Adicione então ToolsAPI no uses do seu package. Por padrão, se você compilar agora, o compilador não vai encontrar essa unit. Não saia procurando ela e alterando seu Library Path ou o Search Path do projeto – não é para você compilar essa unit – ela está dentro de DesignIDE.dcp. Vá no nó de Requires do project manager, clique com o direito e selecione Add Reference, e navegue até a pasta Lib dentro da instalação do seu Delphi, encontrando DesignIDE.dcp lá. Depois de adicionar essa referência, o projeto já compila corretamente encontrando ToolsApi sem problemas.

O Expert mais simples que podemos criar agora é chamado de “Wizard” pela OTA. Você pode abrir ToolsAPI.pas e procurar IOTAWizard lá para ver o que precisamos implementar para criar um Wizard:

  IOTAWizard = interface(IOTANotifier)
    ['{B75C0CE0-EEA6-11D1-9504-00608CCBF153}']
    { Expert UI strings }
    function GetIDString: string;
    function GetName: string;
    function GetState: TWizardState;

    { Launch the AddIn }
    procedure Execute;
  end;

As três primeiras funções devem ser implementadas para retornar um ID único para seu wizard, o nome dele, e o seu estado (que pode ser habilitado, assinalado, os dois ou nenhum). O quarto método que precisamos preencher é o Execute, que é onde vamos colocar nosso código para a ação vai acontecer realmente.

Não adianta muito ter um wizard se ele não aparecer em lugar algum. Vamos implementar a interface IOTAMenuWizard também, para que nosso wizard apareça no menu da IDE. Se você for dar uma olhada no ToolsAPI.pas, ele está declarado assim:

  IOTAMenuWizard = interface(IOTAWizard)
    ['{B75C0CE2-EEA6-11D1-9504-00608CCBF153}']
    function GetMenuText: string;
  end;

Nessa interface, só temos que implementar uma função que retorne o texto que vai aparecer no menu. A interface wizard é descendente de IOTANotifier. Para não precisarmos implementar mais métodos que não vamos usar por enquanto, vamos usar a implementação padrão dessa interface que o ToolsAPI inclui como base, o TNotifierObject. Minha implementação ficou assim:

uses
  Dialogs, ToolsAPI;

type
  TPrimeiroWizard = class(TNotifierObject, IOTAWizard, IOTAMenuWizard)
  public
    // IOTAWizard:
    function GetIDString: string;
    function GetName: string;
    function GetState: TWizardState;
    procedure Execute;
    // IOTAMenuWizard:
    function GetMenuText: string;
  end;

function TPrimeiroWizard.GetIDString: string;
begin
  Result := 'PrimeiroWizard';
end;

function TPrimeiroWizard.GetName: string;
begin
  Result := 'Primeiro Wizard';
end;

function TPrimeiroWizard.GetState: TWizardState;
begin
  Result := [wsEnabled];
end;

procedure TPrimeiroWizard.Execute;
begin
  ShowMessage('Primeiro Wizard!');
end;

function TPrimeiroWizard.GetMenuText: string;
begin
  Result := 'Primeiro Wizard';
end;

Vamos a implementação das duas interfaces, retornando as informações necessárias. Finalmente, precisamos registrar esse wizard para que possamos utilizá-lo. Vamos utilizar a seção de initialization da unit para isso:

initialization
  RegisterPackageWizard(TPrimeiroWizard.Create);

E pronto. Agora basta clicar com o direito na sua package dentro do Project Manager, selecionar Install. Se tudo deu certo, um menu com o caption “Primeiro Wizard” apareceu no item Help do Menu principal da IDE. Clicando nele, uma mensagem dizendo “Primeiro Wizard” aparece.

Partindo disso como modelo, é fácil implementar qualquer coisa que quiser agora dentro do Execute do seu expert. É claro, o menu Help não é o melhor lugar para ter um item de menu, e com certeza você quer acessar mais informações da IDE. Vamos fazer isso da próxima vez!